build.gradle

apply plugin: "java"
apply plugin: "idea"
apply plugin: "eclipse"
apply plugin: "application"

mainClassName = "bpelviz.Main"

repositories {
    mavenCentral()
}

dependencies {
    compile 'net.sf.saxon:Saxon-HE:9.5.1-3'
    compile 'commons-cli:commons-cli:1.2'
    compile 'ch.qos.logback:logback-classic:1.0.13'
    compile 'commons-io:commons-io:2.4'
    testCompile 'junit:junit:4.11'
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.11'
}

run {
    if (project.hasProperty('args')) {
        args project.args.split('\\s+')
    }
}

task sass() << {

    // works only on windows when having the sass gem installed on the path
    try {
    ant.exec(executable: "cmd", failonerror: true) {
        arg(value: "/c")
        arg(value: "sasss")
        arg(value: "src/main/resources/BPELviz.scss")
        arg(value: "src/main/resources/BPELviz.css")
    }
    } catch (Exception e){
        println "ensure that sass is available at the command line and that you use WINDOWS"
        throw e
    }
}

task generateExamples(type: JavaExec, dependsOn: build) {
    description = 'Generates all examples'
    classpath = sourceSets.main.runtimeClasspath
    main = "bpelviz.BetsyTestVisualizer"
}