build.gradle

//file:noinspection GroovyAssignabilityCheck

plugins {
    id("java")
    id("checkstyle")
    id("com.github.spotbugs").version("5.0.5")
    id("org.cadixdev.licenser").version("0.6.1")
    id("com.github.johnrengelman.shadow").version("7.1.2")
}

setGroup("net.elytrium")
setVersion("1.0.11-SNAPSHOT")

compileJava {
    getOptions().setEncoding("UTF-8")
}

java {
    setSourceCompatibility(JavaVersion.VERSION_11)
    setTargetCompatibility(JavaVersion.VERSION_11)
}

repositories {
    mavenCentral()

    maven {
        setName("elytrium-repo")
        setUrl("https://maven.elytrium.net/repo/")
    }
    maven {
        setName("papermc-repo")
        setUrl("https://repo.papermc.io/repository/maven-public/")
    }
    maven {
        setName("opencollab-repo")
        setUrl("https://repo.opencollab.dev/maven-snapshots/")
    }
}

dependencies {
    compileOnly("net.elytrium.limboapi:api:$limboapiVersion")
    compileOnly("net.elytrium:limboauth:$limboauthVersion")
    compileOnly("net.elytrium.commons:config:$elytriumCommonsVersion")
    compileOnly("net.elytrium.commons:utils:$elytriumCommonsVersion")
    compileOnly("net.elytrium.commons:velocity:$elytriumCommonsVersion")
    compileOnly("net.elytrium.commons:kyori:$elytriumCommonsVersion")
    compileOnly("com.velocitypowered:velocity-api:$velocityVersion")
    annotationProcessor("com.velocitypowered:velocity-api:$velocityVersion")

    implementation("net.dv8tion:JDA:$jdaVersion") {
        exclude module: "opus-java"
    }
    implementation("org.telegram:telegrambots:$telegrambotsVersion")
    implementation("com.vk.api:sdk:$vkVersion")

    implementation("com.maxmind.geoip2:geoip2:$geoipVersion")
    implementation("org.apache.commons:commons-compress:$apacheCompressCommonsVersion")

    implementation("org.bstats:bstats-velocity:$bstatsVersion")
    compileOnly("com.github.spotbugs:spotbugs-annotations:$spotbugsVersion")
}

shadowJar {
    getArchiveClassifier().set("")

    exclude("META-INF/maven/**")
    exclude("META-INF/INFO_BIN")
    exclude("META-INF/INFO_SRC")
    exclude("org/slf4j/**")
    exclude("google/protobuf/**")
    exclude("com/google/protobuf/**")
    exclude("org/apache/commons/codec/language/**")
    exclude("org/checkerframework/**")
    exclude("**/package-info.class")

    minimize()

    // Why are we increasing the size of the plugin if we can do that? :thinking:
    relocate("org.bstats", "net.elytrium.limboapi.thirdparty.org.bstats")
    exclude("org/bstats/**")

    relocate("net.dv8tion.jda", "net.elytrium.limboauth.socialaddon.thirdparty.net.dv8tion.jda")
    relocate("org.telegram.telegrambots", "net.elytrium.limboauth.socialaddon.thirdparty.org.telegram.telegrambots")
    relocate("com.vk.api", "net.elytrium.limboauth.socialaddon.thirdparty.com.vk.api")
    relocate("net.elytrium.commons.velocity", "net.elytrium.limboapi.thirdparty.commons.velocity")
    relocate("net.elytrium.commons.kyori", "net.elytrium.limboapi.thirdparty.commons.kyori")
    relocate("net.elytrium.commons.config", "net.elytrium.limboapi.thirdparty.commons.config")
}

license {
    setHeader(file("HEADER.txt"))
}

checkstyle {
    setToolVersion("9.2.1")
    setConfigFile(file("${this.getRootDir()}/config/checkstyle/checkstyle.xml"))
    setConfigProperties("configDirectory": "${this.getRootDir()}/config/checkstyle")

    // The build should immediately fail if we have errors.
    setMaxErrors(0)
    setMaxWarnings(0)
}

spotbugsMain {
    setExcludeFilter(file("${this.getRootDir()}/config/spotbugs/suppressions.xml"))

    reports {
        html {
            getRequired().set(true)
            getOutputLocation().set(file("${this.getBuildDir()}/reports/spotbugs/main/spotbugs.html"))
            setStylesheet("fancy-hist.xsl")
        }
    }
}

sourceSets.main.getJava().srcDir(getTasks().register("generateTemplates", Copy) { task ->
    task.getInputs().properties("version": getVersion())

    task.from(file("src/main/templates"))
            .into(getLayout().getBuildDirectory().dir("generated/sources/templates"))
            .expand("version": getVersion())
}.map {
    it.getOutputs()
})

assemble.dependsOn(shadowJar)