build.gradle

plugins {
    id 'java-library'
    id 'jacoco'
    id 'maven-publish'
    id 'io.github.gradle-nexus.publish-plugin' version '1.2.0'
    id 'signing'
}

apply from: 'gradle/publish.gradle'

group = 'com.github.kuliginstepan'
version = '4.0.0'
sourceCompatibility = JavaVersion.VERSION_17

def nexusUsername = System.getenv("NEXUS_USERNAME") ?: (project.findProperty("NEXUS_USERNAME") ?: "")
def nexusPassword = System.getenv("NEXUS_PASSWORD") ?: (project.findProperty("NEXUS_PASSWORD") ?: "")

nexusPublishing {
    repositories {
        sonatype {
            username = nexusUsername
            password = nexusPassword
        }
    }
}

repositories {
    mavenCentral()
}

java {
    withSourcesJar()
    withJavadocJar()
}

configurations {
    internal {
        visible = false
        canBeConsumed = false
        canBeResolved = false
    }
    annotationProcessor {
        extendsFrom(internal)
    }
    testAnnotationProcessor {
        extendsFrom(internal)
    }
    compileClasspath {
        extendsFrom(internal)
    }
    runtimeClasspath {
        extendsFrom(internal)
    }
    testCompileClasspath {
        extendsFrom(internal)
    }
    testRuntimeClasspath {
        extendsFrom(internal)
    }
}

dependencies {
    internal platform('org.springframework.boot:spring-boot-dependencies:3.0.4')
    implementation 'org.springframework.boot:spring-boot'
    implementation 'org.springframework.boot:spring-boot-autoconfigure'
    implementation 'org.springframework:spring-webflux'
    implementation 'io.projectreactor.netty:reactor-netty'
    implementation 'com.fasterxml.jackson.core:jackson-databind'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310'
    implementation 'org.slf4j:slf4j-api'
    implementation 'jakarta.validation:jakarta.validation-api'
    implementation 'org.hibernate.validator:hibernate-validator'

    compileOnly 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
    annotationProcessor 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

test {
    useJUnitPlatform()
}

jacocoTestReport {
    reports {
        xml.required = true
        csv.required = false
    }
}

test.finalizedBy jacocoTestReport