diff --git a/modules/module-list.nix b/modules/module-list.nix
index 3280682c5..839b2f367 100644
--- a/modules/module-list.nix
+++ b/modules/module-list.nix
@@ -51,6 +51,8 @@
   ./environment
   ./fonts
   ./launchd
+  ./power
+  ./power/sleep.nix
   ./services/activate-system
   ./services/autossh.nix
   ./services/buildkite-agents.nix
diff --git a/modules/power/default.nix b/modules/power/default.nix
new file mode 100644
index 000000000..0e516a94f
--- /dev/null
+++ b/modules/power/default.nix
@@ -0,0 +1,47 @@
+{ config, lib, ... }:
+
+with lib;
+
+let
+  cfg = config.power;
+
+  onOff = cond: if cond then "on" else "off";
+in
+
+{
+  options = {
+    power.restartAfterPowerFailure = mkOption {
+      type = types.nullOr types.bool;
+      default = null;
+      description = lib.mdDoc ''
+        Whether to restart the computer after a power failure.
+      '';
+    };
+
+    power.restartAfterFreeze = mkOption {
+      type = types.nullOr types.bool;
+      default = null;
+      description = lib.mdDoc ''
+        Whether to restart the computer after a system freeze.
+      '';
+    };
+  };
+
+  config = {
+
+    system.activationScripts.power.text = ''
+      echo "configuring power..." >&2
+
+      ${optionalString (cfg.restartAfterPowerFailure != null) ''
+        systemsetup -setRestartPowerFailure \
+          '${onOff cfg.restartAfterPowerFailure}' &> /dev/null
+      ''}
+
+      ${optionalString (cfg.restartAfterFreeze != null) ''
+        systemsetup -setRestartFreeze \
+          '${onOff cfg.restartAfterFreeze}' &> /dev/null
+      ''}
+    '';
+
+  };
+}
diff --git a/modules/power/sleep.nix b/modules/power/sleep.nix
new file mode 100644
index 000000000..14ad4b4fe
--- /dev/null
+++ b/modules/power/sleep.nix
@@ -0,0 +1,80 @@
+{ config, lib, ... }:
+
+with lib;
+
+let
+  cfg = config.power.sleep;
+
+  onOff = cond: if cond then "on" else "off";
+in
+
+{
+  options = {
+    power.sleep.computer = mkOption {
+      type = types.nullOr (types.either types.ints.positive (types.enum ["never"]));
+      default = null;
+      example = "never";
+      description = lib.mdDoc ''
+        Amount of idle time (in minutes) until the computer sleeps.
+
+        `"never"` disables computer sleeping.
+
+        The system might not be considered idle before connected displays sleep, as
+        per the `power.sleep.display` option.
+      '';
+    };
+
+    power.sleep.display = mkOption {
+      type = types.nullOr (types.either types.ints.positive (types.enum ["never"]));
+      default = null;
+      example = "never";
+      description = lib.mdDoc ''
+        Amount of idle time (in minutes) until displays sleep.
+
+        `"never"` disables display sleeping.
+      '';
+    };
+
+    power.sleep.harddisk = mkOption {
+      type = types.nullOr (types.either types.ints.positive (types.enum ["never"]));
+      default = null;
+      example = "never";
+      description = lib.mdDoc ''
+        Amount of idle time (in minutes) until hard disks sleep.
+
+        `"never"` disables hard disk sleeping.
+      '';
+    };
+
+    power.sleep.allowSleepByPowerButton = mkOption {
+      type = types.nullOr types.bool;
+      default = null;
+      description = lib.mdDoc ''
+        Whether the power button can sleep the computer.
+      '';
+    };
+  };
+
+  config = {
+
+    system.activationScripts.sleep.text = ''
+      ${optionalString (cfg.computer != null) ''
+        systemsetup -setComputerSleep '${toString cfg.computer}' &> /dev/null
+      ''}
+
+      ${optionalString (cfg.display != null) ''
+        systemsetup -setDisplaySleep '${toString cfg.display}' &> /dev/null
+      ''}
+
+      ${optionalString (cfg.harddisk != null) ''
+        systemsetup -setHardDiskSleep '${toString cfg.harddisk}' &> /dev/null
+      ''}
+
+      ${optionalString (cfg.allowSleepByPowerButton != null) ''
+        systemsetup -setAllowPowerButtonToSleepComputer \
+          '${onOff cfg.allowSleepByPowerButton}' &> /dev/null
+      ''}
+    '';
+
+  };
+}
diff --git a/modules/system/activation-scripts.nix b/modules/system/activation-scripts.nix
index 832519986..367c017be 100644
--- a/modules/system/activation-scripts.nix
+++ b/modules/system/activation-scripts.nix
@@ -67,6 +67,8 @@ in
       ${cfg.activationScripts.nix-daemon.text}
       ${cfg.activationScripts.time.text}
       ${cfg.activationScripts.networking.text}
+      ${cfg.activationScripts.power.text}
+      ${cfg.activationScripts.sleep.text}
       ${cfg.activationScripts.keyboard.text}
       ${cfg.activationScripts.fonts.text}
       ${cfg.activationScripts.nvram.text}