-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathArpmini_plus.ino
2663 lines (2229 loc) · 72.8 KB
/
Arpmini_plus.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*!
* @file Arpmini_plus.ino
* Project Estorm - Arpmini+
* @brief MIDI Sequencer & Arpeggiator
* @version 2.04
* @author Paolo Estorm
* @date 09/12/24
* @license GPL v3.0
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
// Inspired by the "arduino based midi sequencer" project by Brendan Clarke
// https://brendanclarke.com/wp/2014/04/23/arduino-based-midi-sequencer/
#include "Vocabulary.h"
// system
char version[] = "2.04";
// leds
#define redled 3 // red led pin
#define yellowled 2 // yellow led pin
#define greenled 4 // green led pin
#define blueled 5 // blue led pin
// sound
#define speaker 21 // buzzer pin
bool uisound = true; // is ui sound on?
uint8_t soundmode = 1; // 1 audio on, 2 ui sounds off, 3 off
bool sound = true; // speaker sound toggle
bool metro = false; // metronome toggle
bool confirmsound = false; // at button press, play the confirmation sound instead of the click
// screen
#define OLED_SPI_SPEED 8000000ul // set SPI at 8MHz
#include "GyverOLED.h"
#define RES 19 // SPI reset pin
#define DC 20 // SPI DC pin
#define CS 18 // SPI CS pin
GyverOLED<CS, DC, RES> oled; // screen initialization
bool StartScreenTimer = true; // activate the screen-on timer
// memory
#include <EEPROM.h>
// midi
#include <MIDI.h>
#include <SoftwareSerial.h>
SoftwareSerial Serial2(10, -1); // midi2 pins (input, output)
MIDI_CREATE_INSTANCE(HardwareSerial, Serial1, MIDI); // initialize midi1
MIDI_CREATE_INSTANCE(SoftwareSerial, Serial2, MIDI2); // initialize midi2
uint8_t midiChannel = 1; // MIDI channel to use for sequencer 1 to 16
int8_t syncport = 1; // activate midi-in sync 0=none, 1=port1, 2=port2
// buttons
#define redbutton 7 // red button pin
#define yellowbutton 6 // yellow button pin
#define greenbutton 8 // green button pin
#define bluebutton 9 // blue button pin
bool EnableButtons = true; // if controlled externally (by CC) disable all buttons
uint8_t greentristate = 1; // 0=off, 1=null, 2=on
bool redstate = false; // is redbutton pressed?
bool yellowstate = false; // is yellowbutton pressed?
bool greenstate = false; // is greenbutton pressed?
bool bluestate = false; // is bluebutton pressed?
uint8_t redbuttonCC; // cc for external control
uint8_t yellowbuttonCC; // cc for external control
uint8_t bluebuttonCC; // cc for external control
uint8_t greenbuttonCC; // cc for external control
int8_t numbuttonspressedCC = 0; // number of externally pressed buttons
uint8_t mapButtonSelect = 1; // 1=red, 2=yellow, 3=blue, 4=green
// menu
uint8_t menuitem = 2; // is the number assiciated with every voice in the main menu. 0 to 16
uint8_t menunumber = 0; // 0=mainscreen, 1=menu, 2=submenu, 3=load\save menu
uint8_t savemode = 0; // 0=new, 1=save, 2=load, 3=delete
uint8_t savecurX = 0; // cursor position in load/save menu 0-5
bool confirmation = false; // confirmation popup in load/save menu
bool full = false; // is the selected save slot full?
int8_t curpos = 0; // cursor position in songmode, 0-7
bool PrintSongLiveCursor = false; // send the cursor to screen, song & live mode
bool PrintTimeBar = false; // send the BPM bar to screen
bool StartMenuTimer = true; // activate the go-to-menu timer
// time keeping
volatile uint8_t clockTimeout; // variable for keeping track of external/internal clock
uint8_t StepSpeed = 2; // 1=2x, 2=1x, 3=3/4, 4=1/2
bool FixSync = false; // tries to re-allign the sequence when changing step-speeds
bool internalClock = true; // is the sequencer using the internal clock (otherwise external sync)?
bool flipflopEnable; // part of the frameperstep flipflop
uint8_t sendrealtime = 1; // send midi realtime messages. 0=off, 1=on (@internalclock, only if playing), 2=on (@internalclock, always)
int8_t GlobalStep; // keep track of note steps only for metronome and tempo indicator in arp mode
int8_t tSignature = 4; // time signature for led indicator/metronome and beats, 1 - 8 (1*/4, 2*/4..to 8/4)
int8_t GlobalDivison = 4; // how many steps per beat
int8_t countBeat; // keep track of the time beats
int8_t countStep; // keep track of note steps in seq/song mode
int8_t IntercountStep; // keep track of note steps while inter-recording
int8_t countTicks; // the frame number (frame=external clock or 24 frames per quarter note)
uint8_t ticksPerStep = 6; // how many clock ticks to count before the sequencer moves to another step.
uint8_t flip = 6; // part of the frameperstep's flipflop
uint8_t flop = 6; // part of the frameperstep's flipflop
bool swing = false; // is swing enabled?
uint8_t BPM = 120; // beats per minute for internalclock - min 20, max 250 bpm
bool playing = false; // is the sequencer playing?
uint8_t snapmode = 1; // when play/stop the next sequence in live mode. 0=pattern, 1=up-beat, 2=beat
bool start = false; // dirty fix for a ableton live 10 bug. becomes true once at sequence start and send a sync command
// arpeggiator
const uint8_t holdNotes = 8; // maximum number of notes that can be held at once
int8_t activeNotes[holdNotes]; // contains the MIDI notes the arpeggiator plays
bool ArpDirection; // alternate up-down for arpstyle 3 & 4
uint8_t arpstyle = 1; // 1=up, 2=down, 3=up-down, 4=down-up, 5=up+down, 6=down+up, 7=random
uint8_t arpcount; // number of times the arpeggio repeats
uint8_t arprepeat = 1; // number of times the arpeggios gets trasposed by "stepdistance"
int8_t stepdistance = 12; // distance in semitones between each arp repeat, -12 to +12
int8_t numNotesHeld = 0; // how many notes are currently pressed on the keyboard
int8_t numActiveNotes = 0; // number of notes currently stored in the holdNotes array
uint8_t trigMode = 0; // 0=hold, 1=trigger, 2=retrigged
// sequencer
bool recording = false; // is the sequencer in the recording state?
uint8_t rolandLowNote; // for 'roland' mode, the sequence is transposed based on the lowest note recorded
uint8_t rolandTransposeNote; // the last note number received for transposing the sequence
uint8_t seqLength = 16; // the number of steps the sequence is looped for - can be less than maxSeqLength
uint8_t NewSeqLength = 16; // 1-32 seq.length of the newly created song
uint8_t currentSeq = 0; // the currently selected sequence row from the big matrix below. 0=seq1, 1=seq2, 2=seq3, 3=seq4
uint8_t newcurrentSeq = 0; // the next sequence is going to play in live mode. 0-3
const uint8_t maxSeqLength = 32; // the total possible number of steps (columns in the big matrix below)
const uint8_t numberSequences = 4; // the number of total sequences
int8_t noteSeq[numberSequences][maxSeqLength]; // sequences arrays
const uint8_t patternLength = 8; // number of patterns
uint8_t songPattern[patternLength]; // pattern array
uint8_t pattern = 0; // currently playing pattern
bool chainrec = false; // sequential recording in song mode?
bool lockpattern = false; // if true block the current pattern from sequencing
// notes
int8_t pitch = 0; // pitch transposition: -12 to +12
bool pitchmode = false; // 0=before scale, 1=scale root
uint8_t scale = 0; // 0=linear, 1=penta. major, 2=penta. minor, 3=major, 4=minor, 5=arabic, 6=locrian, 7=lydian, 8=dorian, 9=inverted, 10=hexa.
int8_t posttranspose = 0; // post-scale pitch transposition: -12 to +12
uint8_t noteLengthSelect = 3; // set the notelength, 0=random, 1=10%, 2=30%, 3=50%, 4=80%, 5=100%, 6=120%
bool sortnotes = true; // sort the ActiveNotes array?
bool muted = false; // temporarily suspend playing any notes from the sequencer
bool TrigMute = false; // toggle mute in sync with snapmode, in live mode
bool sustain = false; // hold notes also if trigmode > 0
const uint8_t queueLength = 2; // the number of notes that can overlap if notelenght is 120%
int8_t cronNote[queueLength]; // stores the notes playing
int8_t cronLength[queueLength]; // stores the amount of time a note has left to play
// general
uint8_t modeselect = 1; // 1=arp.mode, 2=rec.mode, 3=song mode, 4=live mode
uint8_t premodeselect = 1; // pre-selection of the mode in submenu
void setup() { // initialization setup
// oled screen initialization
oled.init();
oled.clear();
oled.setScale(3);
// disable onboard LEDs
pinMode(LED_BUILTIN_TX, INPUT);
pinMode(LED_BUILTIN_RX, INPUT); // pin 17
// initialize pins
pinMode(redled, OUTPUT);
pinMode(yellowled, OUTPUT);
pinMode(greenled, OUTPUT);
pinMode(blueled, OUTPUT);
pinMode(speaker, OUTPUT);
AllLedsOff();
pinMode(redbutton, INPUT_PULLUP);
pinMode(yellowbutton, INPUT_PULLUP);
pinMode(bluebutton, INPUT_PULLUP);
pinMode(greenbutton, INPUT_PULLUP);
// initialize timer1 used for internal clock
noInterrupts();
TCCR1A = 0; // set TCCR1A register to 0
TCCR1B = 0; // same for TCCR1B
TCNT1 = 0; // initialize counter value to 0
OCR1A = 5208; // initial tempo 120bpm
TCCR1B |= (1 << WGM12); // turn on CTC mode
TCCR1B |= (1 << CS11); // 64 prescaler
TCCR1B |= (1 << CS10); // 64 prescaler
TIMSK1 |= (1 << OCIE1A); // enable timer compare interrupt
interrupts();
// midi initialization settings
MIDI.begin(MIDI_CHANNEL_OMNI);
MIDI2.begin(MIDI_CHANNEL_OMNI);
MIDI.turnThruOff();
MIDI2.turnThruOff();
MIDI.setHandleControlChange(HandleCC);
MIDI2.setHandleControlChange(HandleCC);
MIDI.setHandleNoteOn(HandleNoteOn);
MIDI2.setHandleNoteOn(HandleNoteOn);
MIDI.setHandleNoteOff(HandleNoteOff);
MIDI2.setHandleNoteOff(HandleNoteOff);
MIDI.setHandleSongPosition(HandleSongPosition);
MIDI2.setHandleSongPosition(HandleSongPosition);
if (EEPROM.read(15) != 64) ResetEEPROM(); // if check is not valid, initialize the EEPROM with default values
midiChannel = EEPROM.read(0);
sendrealtime = EEPROM.read(1);
soundmode = EEPROM.read(2);
syncport = EEPROM.read(3);
redbuttonCC = EEPROM.read(4);
yellowbuttonCC = EEPROM.read(5);
bluebuttonCC = EEPROM.read(6);
greenbuttonCC = EEPROM.read(7);
SetBPM(BPM);
SetSound(soundmode);
SetSyncPort(syncport);
ClearSeqPatternArray();
Startposition();
SynthReset();
Bip(2); // Startup Sound
oled.println(F("ARPMINI"));
oled.print(F(" +"));
oled.setScale(1);
oled.setCursorXY(25, 56);
oled.print(F("FIRMWARE "));
oled.print(version);
delay(2000);
PrintMainScreen();
}
void loop() { // run continuously
MIDI.read();
MIDI2.read();
DebounceButtons();
ScreenOnTimer();
GoToMenuTimer();
if (PrintSongLiveCursor) {
PrintSongLiveCursor = false;
PrintPatternSequenceCursor();
}
if (PrintTimeBar) {
PrintTimeBar = false;
PrintBPMBar();
}
}
void ResetEEPROM() { // initialize the EEPROM with default values
for (uint8_t i = 0; i < 6; i++) {
if (i < 4) {
EEPROM.write(i, 1); // midiChannel, sendrealtime, soundmode, syncport
EEPROM.write(4 + i, i + 21); // buttons cc
}
EEPROM.write(16 + (144 * i), 0); // songs addresses
}
EEPROM.write(15, 64); // write check
}
void AllLedsOn() { // turn on all leds
digitalWrite(redled, HIGH);
digitalWrite(yellowled, HIGH);
digitalWrite(blueled, HIGH);
digitalWrite(greenled, HIGH);
}
void AllLedsOff() { // turn of all leds
digitalWrite(redled, LOW);
digitalWrite(yellowled, LOW);
digitalWrite(blueled, LOW);
digitalWrite(greenled, LOW);
}
void GoToMenuTimer() { // greenbutton longpress enter the menu
static unsigned long SampleMenuTime; // time in ms at which the timer was set
static bool MenuTimerState; // is the timer still running?
if (StartMenuTimer) {
StartMenuTimer = false;
MenuTimerState = true;
SampleMenuTime = millis();
}
if (MenuTimerState) {
if (greentristate == 2) {
if (millis() - SampleMenuTime > 1000) {
MenuTimerState = false;
greentristate = 1;
Bip(2);
if (modeselect == 4) menuitem = 2;
PrintMenu(menuitem);
if (recording) {
recording = false;
ManageRecording();
}
}
}
}
}
void ScreenOnTimer() { // in the main screen if greenbutton is held for 4 seconds, go to menu
static unsigned long SampleTime = 0; // Time at which the timer was set
static bool TimerState = false; // Is the timer still running?
// Start the timer
if (StartScreenTimer) {
StartScreenTimer = false;
TimerState = true;
SampleTime = millis();
oled.sendCommand(OLED_DISPLAY_ON);
oled.setContrast(255);
}
// If the timer is running, check if it has expired
if (TimerState && millis() - SampleTime > 4000) {
TimerState = false;
// Check if the screen should be turned off or dimmed
if (menunumber == 0 && ((modeselect != 3) || (modeselect == 3 && !playing && internalClock))) {
oled.sendCommand(OLED_DISPLAY_OFF);
} else {
oled.setContrast(1);
}
}
}
void SynthReset() { // clear cache
for (uint8_t i = 0; i < holdNotes; i++) {
activeNotes[i] = -1;
if (i < queueLength) {
cronNote[i] = -1;
cronLength[i] = -1;
}
}
numNotesHeld = 0;
AllNotesOff();
}
void AllNotesOff() { // send allnoteoff control change
MIDI.sendControlChange(123, 0, midiChannel);
}
void ConnectPort(uint8_t portselect) { // connects sync ports
if (portselect == 1) {
MIDI.setHandleClock(HandleClock);
MIDI.setHandleStart(HandleStart);
MIDI.setHandleStop(HandleStop);
MIDI.setHandleContinue(HandleContinue);
} else if (portselect == 2) {
MIDI2.setHandleClock(HandleClock);
MIDI2.setHandleStart(HandleStart);
MIDI2.setHandleStop(HandleStop);
MIDI2.setHandleContinue(HandleContinue);
}
}
void DisconnectPort(uint8_t portselect) { // disconnects sync ports
if (portselect == 1) {
MIDI.disconnectCallbackFromType(midi::Clock);
MIDI.disconnectCallbackFromType(midi::Start);
MIDI.disconnectCallbackFromType(midi::Stop);
MIDI.disconnectCallbackFromType(midi::Continue);
} else if (portselect == 2) {
MIDI2.disconnectCallbackFromType(midi::Clock);
MIDI2.disconnectCallbackFromType(midi::Start);
MIDI2.disconnectCallbackFromType(midi::Stop);
MIDI2.disconnectCallbackFromType(midi::Continue);
}
}
void SetSyncPort(uint8_t port) { // 0-none, 1-port1, 2-port2 define port for external sync
DisconnectPort(1);
DisconnectPort(2);
if (port == 1) {
ConnectPort(1);
} else if (port == 2) {
ConnectPort(2);
}
}
unsigned short int eepromaddress(unsigned short int address, uint8_t slot) { // calculate eeprom addresses // (address, slot number 0-5)
return (144 * slot) + address;
}
void ScreenBlink(bool mode = false) { // blinks screen - 0 bip on button-press, 1 bip regardless
oled.sendCommand(OLED_DISPLAY_OFF);
oled.sendCommand(OLED_DISPLAY_ON);
if (!mode) confirmsound = true;
else Bip(2);
}
void SetSound(uint8_t mode) { // sound settings
if (mode == 1) {
sound = true;
uisound = true;
} else if (mode == 2) {
uisound = false;
sound = true;
} else if (mode == 3) sound = false;
}
void Bip(uint8_t type) { // sounds
if (sound) {
if (uisound) {
if (type == 1) tone(speaker, 3136, 1); // click
else if (type == 2) tone(speaker, 2637, 10); // startup/confirmation
}
if (type == 3) tone(speaker, 3136, 10); // metronome
else if (type == 4) tone(speaker, 2349, 3); // metronome
}
}
void SetBPM(uint8_t tempo) { // change Timer1 speed to match BPM, 20-250
OCR1A = (25 * (25000 / tempo)); // 2.5*[(16MHz/prescaler)/BPM]
}
ISR(TIMER1_COMPA_vect) { // internal clock
static const uint8_t MaxClockTimeout = 100;
if (internalClock) {
if ((sendrealtime == 1 && playing) || (sendrealtime == 2)) MIDI.sendRealTime(midi::Clock);
RunClock();
} else {
clockTimeout++;
if (clockTimeout > MaxClockTimeout) {
HandleStop();
}
}
}
void HandleClock() { // external clock
if (!internalClock) {
clockTimeout = 0;
RunClock();
if (sendrealtime) MIDI.sendRealTime(midi::Clock);
}
}
void RunClock() { // main clock
countTicks = (countTicks + 1) % ticksPerStep;
if (countTicks == 0) {
if (start) {
start = false;
if (sendrealtime) MIDI.sendSongPosition(0); // make ableton live happy, without would be slightly out of sync
}
if ((modeselect != 4 && (!internalClock || (internalClock && playing))) || modeselect == 4) HandleStep();
}
if (countTicks == 2) {
if (menunumber == 0) {
if (modeselect != 4 && (!recording || (recording && playing))) digitalWrite(yellowled, LOW); // turn yellowled off before 2 ticks - Tempo indicator
else if (modeselect == 4) {
if (playing) AllLedsOff();
}
}
}
if (modeselect < 3) { // not song & live mode
if (trigMode > 0 && numNotesHeld == 0 && !sustain) muted = true;
}
for (uint8_t i = 0; i < queueLength; i++) { // decrement crons
if (cronLength[i] > -1) {
cronLength[i] = cronLength[i] - SetNoteLength(); // this number is subtracted from the cronLength buffer for each frame a note is active
}
if (cronLength[i] < -1) {
MIDI.sendNoteOff(cronNote[i], 0, midiChannel);
cronLength[i] = -1;
cronNote[i] = -1;
}
}
}
void SetTicksPerStep() { // set ticksPerStep values
switch (StepSpeed) {
case 1: // 2x
flip = swing ? 4 : 3;
flop = swing ? 2 : 3;
GlobalDivison = 8;
break;
case 2: // 1x
flip = swing ? 8 : 6;
flop = swing ? 4 : 6;
GlobalDivison = 4;
break;
case 3: // 3/4
flip = 8;
flop = 8;
GlobalDivison = 3;
break;
case 4: // 1/2
flip = swing ? 16 : 12;
flop = swing ? 8 : 12;
GlobalDivison = 2;
break;
}
}
void FlipFlopFPS() { // alternates ticksPerStep values (for swing)
flipflopEnable = !flipflopEnable;
if (flipflopEnable) ticksPerStep = flip;
else ticksPerStep = flop;
}
uint8_t SetNoteLength() { // set the note duration
uint8_t noteLength;
static const uint8_t noteLengths[] = { 55, 35, 30, 25, 20, 15 }; // noteLengths
if (noteLengthSelect == 0) { // random
noteLength = random(15, 55);
} else noteLength = noteLengths[noteLengthSelect - 1];
if (swing && StepSpeed != 3) {
if (flipflopEnable) noteLength = noteLength - 5;
else noteLength = noteLength + 10;
}
if (StepSpeed == 1) noteLength = noteLength * 2;
else if (StepSpeed == 3) noteLength = noteLength - 5;
else if (StepSpeed == 4) noteLength = noteLength / 2;
return (noteLength);
}
void HandleStep() { // step sequencer
GlobalStep++;
if (GlobalStep > (GlobalDivison - 1)) {
GlobalStep = 0;
}
if (FixSync) {
if (GlobalStep == 0) {
Startposition();
FixSync = false;
}
} else SetTicksPerStep();
FlipFlopFPS();
if (modeselect == 1) { // arp.mode
if (numActiveNotes > 0) {
SetArpStyle(arpstyle); // arp sequencer
if (!muted && playing) {
QueueNote(activeNotes[countStep % numActiveNotes]); // enqueue and play
}
} else countStep = -1;
}
else if (modeselect != 1) { // rec. & song mode
countStep = (countStep + 1) % seqLength; // seq. sequencer
if (modeselect == 2 || modeselect == 3) {
if (playing && recording && bluestate && menunumber == 0) { // in rec.mode bluebutton delete note
noteSeq[currentSeq][countStep] = -1;
}
if (!playing && recording && internalClock) { // in recording and not playing yellowled indicate steps
if (countStep % 4 == 0) {
digitalWrite(yellowled, HIGH);
} else digitalWrite(yellowled, LOW);
}
if (modeselect == 3) { // call pattern sequencer
if (countStep == 0) {
if ((!recording) || (recording && chainrec)) {
HandlePattern();
}
}
}
}
else if (modeselect == 4) {
if ((snapmode == 0 && countStep == 0) || (snapmode == 1 && GlobalStep == 0 && countBeat == (tSignature - 1)) || (snapmode == 2 && GlobalStep == 0)) {
if (TrigMute) {
TrigMute = false;
muted = !muted;
}
if (currentSeq != newcurrentSeq) {
currentSeq = newcurrentSeq;
muted = false;
if (menunumber == 0) PrintSongLiveCursor = true;
}
}
}
if (playing && (noteSeq[currentSeq][countStep] >= 0) && !muted) { // step has a note - enqueue and play
int8_t note;
if (recording) {
note = noteSeq[currentSeq][countStep];
} else note = (noteSeq[currentSeq][countStep] + rolandTransposeNote - rolandLowNote);
QueueNote(note);
}
}
if (GlobalStep == 0) {
HandleBeat();
}
if (menunumber == 0 && modeselect == 4) { // live mode blinking
if (GlobalStep == 0 || (TrigMute && !(GlobalStep % 2))) {
if (playing) {
if (!muted || TrigMute) {
if (currentSeq == 0) digitalWrite(redled, HIGH);
else if (currentSeq == 1) digitalWrite(yellowled, HIGH);
else if (currentSeq == 2) digitalWrite(blueled, HIGH);
else if (currentSeq == 3) digitalWrite(greenled, HIGH);
} else AllLedsOn();
}
}
}
}
void HandleBeat() { // tempo indicator and metronome
countBeat = (countBeat + 1) % tSignature;
if (menunumber == 0) {
if (modeselect != 4) { // turn yellowled on every beat
if (playing) digitalWrite(yellowled, HIGH);
}
}
if (playing && (recording || metro)) Metronome();
}
void HandlePattern() { // pattern sequencer in songmode
if (!lockpattern) {
pattern = (pattern + 1) % patternLength;
SkipPattern();
}
currentSeq = songPattern[pattern] - 1;
if (menunumber == 0) PrintSongLiveCursor = true;
}
void SkipPattern() { // skip pattern if empty
if ((songPattern[pattern]) == 0) pattern = (pattern + 1) % patternLength;
if ((songPattern[pattern]) == 0) SkipPattern();
}
void Metronome() { // manage the metronome
if (countBeat == 0) Bip(3);
else Bip(4);
}
void HandleStart() { // start message - re-start the sequence
if (sendrealtime) {
MIDI.sendRealTime(midi::Start);
}
internalClock = false;
playing = true;
Startposition();
if (menunumber == 0) { // switch on display and restart screen-on timer
StartScreenTimer = true;
PrintTimeBar = true;
}
}
void HandleContinue() { // continue message - re-start the sequence
HandleStop();
HandleStart();
}
void HandleStop() { // stop the sequence and switch over to internal clock
if (sendrealtime) MIDI.sendRealTime(midi::Stop);
if (menunumber == 0) {
if (modeselect != 4) digitalWrite(yellowled, LOW); // turn yellowled off before 2 ticks - Tempo indicator
else AllLedsOff();
}
playing = false;
internalClock = true;
Startposition();
numNotesHeld = 0;
if (menunumber == 0) { // switch on display and restart screen-on timer
StartScreenTimer = true;
PrintTimeBar = true;
}
}
void StartAndStop() { // manage starts and stops
playing = !playing;
if (internalClock) {
Startposition();
if (sendrealtime) {
if (playing) {
MIDI.sendRealTime(midi::Start);
start = true; // to make ableton live 10 happy
} else MIDI.sendRealTime(midi::Stop);
}
}
}
void HandleSongPosition(unsigned int position) { // send song position midi messages
if (sendrealtime) MIDI.sendSongPosition(position);
}
void Startposition() { // called every time the sequencing start or stop
SetTicksPerStep();
if (!FixSync) {
GlobalStep = -1;
countBeat = -1;
countTicks = -1;
}
if (numNotesHeld > 0) AllNotesOff();
arpcount = 0;
countStep = -1;
flipflopEnable = false;
ArpDirection = true;
if (playing && modeselect == 3) {
if ((!recording) || (recording && chainrec)) {
if (!lockpattern) {
pattern = -1;
}
}
}
if (menunumber == 2 && menuitem == 3) { // refresh BPM page
PrintSubmenu(3);
}
}
void HandleCC(uint8_t channel, uint8_t cc, uint8_t value) { // handle midi CC messages
if (channel == midiChannel) {
if ((cc != 64) && (cc != 123)) { // not sustain pedal or all notes off cc
if (menunumber == 2 && menuitem == 15) { // if cc mapping mode
EnableButtons = true;
if (value > 0) {
if (mapButtonSelect == 1) redbuttonCC = cc;
else if (mapButtonSelect == 2) yellowbuttonCC = cc;
else if (mapButtonSelect == 3) bluebuttonCC = cc;
else if (mapButtonSelect == 4) greenbuttonCC = cc;
PrintSubmenu(menuitem);
StartScreenTimer = true;
Bip(2);
} else {
mapButtonSelect++;
PrintSubmenu(menuitem);
if (mapButtonSelect > 4) {
mapButtonSelect = 1;
ScreenBlink(1);
EEPROM.update(4, redbuttonCC);
EEPROM.update(5, yellowbuttonCC);
EEPROM.update(6, bluebuttonCC);
EEPROM.update(7, greenbuttonCC);
PrintMenu(menuitem);
}
}
}
else { // external control
bool *state = nullptr;
if (cc == redbuttonCC) state = &redstate;
else if (cc == yellowbuttonCC) state = &yellowstate;
else if (cc == bluebuttonCC) state = &bluestate;
else if (cc == greenbuttonCC) state = &greenstate;
if (state) {
*state = value;
numbuttonspressedCC += (*state ? 1 : -1);
ButtonsCommands(*state);
}
EnableButtons = (numbuttonspressedCC == 0);
if (numbuttonspressedCC < 0) numbuttonspressedCC = 0;
}
}
else if (cc == 64) { // sustain pedal cc
sustain = value;
if (!playing || (playing && trigMode == 0)) MIDI.sendControlChange(cc, value, channel); // pass through sustain pedal cc
}
} else MIDI.sendControlChange(cc, value, channel);
}
void HandleNoteOn(uint8_t channel, uint8_t note, uint8_t velocity) { // handle a noteOn event
if (channel == midiChannel) {
if (!playing /*&& !recording*/) { // bypass if not playing
note = TransposeAndScale(note);
MIDI.sendNoteOn(note, velocity, channel);
}
if (modeselect == 1) { // arp mode
if (playing) {
if (numNotesHeld <= 0) { // clear the activeNotes array
numActiveNotes = 0;
for (uint8_t i = 0; i < holdNotes; i++) {
activeNotes[i] = -1;
}
}
if (numActiveNotes < holdNotes) { // store the note only if the activeNotes array is not full
activeNotes[numActiveNotes] = note;
numActiveNotes++;
SortArray(); // sort the activeNotes array
}
}
}
else if (modeselect != 1) { // not arp mode
if (recording) {
if (playing) {
if ((countTicks + 2) > (ticksPerStep / 2)) {
noteSeq[currentSeq][(countStep + 1) % seqLength] = note; // recording & playing
} else {
noteSeq[currentSeq][countStep] = note;
QueueNote(note);
}
} else { // recording & !playing
HandleStep();
noteSeq[currentSeq][countStep] = note;
QueueNote(note);
}
} else if (!recording && playing) rolandTransposeNote = note; // in recmode transpose to note only if playing
}
if (modeselect < 3) { // not song & live mode
if (trigMode > 0) {
muted = false;
if ((trigMode == 2) && (numNotesHeld == 1)) { // trigmode 2 retrig start sequence
Startposition();
if (sendrealtime) {
if (internalClock) {
MIDI.sendSongPosition(0);
}
}
}
}
}
numNotesHeld++;
} else MIDI.sendNoteOn(note, velocity, channel);
}
void HandleNoteOff(uint8_t channel, uint8_t note, uint8_t velocity) { // handle a noteOff event
if (channel == midiChannel) {
if (!playing /* && !recording*/) { // pass trough note off messages
note = TransposeAndScale(note);
MIDI.sendNoteOff(note, velocity, channel);
}
numNotesHeld--;
if (numNotesHeld < 0) numNotesHeld = 0;
if (modeselect == 1 && trigMode > 0 && !sustain) { // arp mode
if (numNotesHeld == 0) muted = true;
for (uint8_t i = 0; i < holdNotes; i++) {
if (activeNotes[i] == note) {
activeNotes[i] = -1;
numActiveNotes--;
SortArray();
}
}
}
} else MIDI.sendNoteOff(note, velocity, channel);
}
void SortArray() { // sort activeNotes array
if (sortnotes) { // sort from small to large
for (uint8_t i = 0; i < holdNotes - 1; i++) {
for (uint8_t j = 0; j < holdNotes - 1; j++) {
if (activeNotes[j + 1] < activeNotes[j] && activeNotes[j + 1] >= 0) {
int8_t temp = activeNotes[j + 1];
activeNotes[j + 1] = activeNotes[j];
activeNotes[j] = temp;
}
}
}
}
if (trigMode == 0) { // remove duplicates and replace them with -1
for (uint8_t i = 0; i < holdNotes - 1; i++) {
if ((activeNotes[i] > 0) && (activeNotes[i] == activeNotes[i + 1])) {
activeNotes[i + 1] = -1;
numActiveNotes--;
}
}
}
for (uint8_t i = 0; i < holdNotes - 1; i++) { // shift all the -1s to the right
if (activeNotes[i] == -1) {
int8_t temp = activeNotes[i + 1];
activeNotes[i + 1] = activeNotes[i];
activeNotes[i] = temp;
}
}
}
uint8_t SetScale(int8_t note, uint8_t scale) { // filter incoming note to fit in to a music scale
static const PROGMEM int8_t scaleOffsets[][12] = {
{ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 }, // Scale 0: Linear
{ 0, -1, -2, -1, -2, -1, -2, -3, -1, -2, -1, -2 }, // Scale 1: Pentatonic Major
{ 0, -1, -2, 0, -1, 0, -1, 0, -1, -2, 0, -1 }, // Scale 2: Pentatonic Minor
{ 0, -1, 0, -1, 0, 0, -1, 0, -1, 0, -1, 0 }, // Scale 3: Major
{ 0, -1, 0, 0, -1, 0, -1, 0, 0, -1, 0, -1 }, // Scale 4: Minor
{ 0, -1, 0, 0, -1, 0, -1, 0, 0, -1, +1, 0 }, // Scale 5: Arabic
{ 0, -1, -2, 0, -1, 0, 0, 0, -1, -2, 0, -1 }, // Scale 6: Blues
{ 0, 0, -1, 0, -1, 0, 0, -1, 0, -1, 0, -1 }, // Scale 7: Locrian
{ 0, -1, 0, -1, 0, -1, 0, 0, -1, 0, -1, 0 }, // Scale 8: Lydian
{ 0, -1, 0, 0, -1, 0, -1, 0, -1, 0, 0, -1 }, // Scale 9: Dorian
{ 11, 9, 7, 5, 3, 1, -1, -3, -5, -7, -9, -11 }, // Scale 10: Inverted
{ 0, -1, 0, -1, 0, -1, 0, -1, 0, -1, 0, -1 } // Scale 11: Hexatonal
};
uint8_t reminder = note % 12;
int8_t offset = pgm_read_byte(&scaleOffsets[scale][reminder]); // read from PROGMEM
return note + offset;
}
uint8_t TransposeAndScale(short int note) { // apply transposition and scale