Nushell script for granted

[abusch]

Hi, I'm a nushell user and I wanted to try out granted so I tried to port the assume wrapper script. This is what I came up with, in case it's useful to someone else:

# Save this file to `granted.nu` in your nushell config dir, then add `source granted.nu` in your config.nu
const var_names = ["AWS_ACCESS_KEY_ID", "AWS_SECRET_ACCESS_KEY", "AWS_SESSION_TOKEN", "AWS_PROFILE", "AWS_REGION", "AWS_SESSION_EXPIRATION", "GRANTED_SSO", "GRANTED_SSO_START_URL", "GRANTED_SSO_ROLE_NAME", "GRANTED_SSO_REGION", "GRANTED_SSO_ACCOUNT_ID"]

def --env --wrapped assume [...rest: string] {
  $env.GRANTED_ALIAS_CONFIGURED = "true"
  let output = (assumego $rest) |
    lines
  # First line is the command
  let command = $output | get -i 0 | default "" | split row " "
  # The rest of the output (if any) is the output of whatever command was run via --exec for instance
  let output = $output | skip 1

  let flag = $command | get 0

  match $flag {
    "GrantedOutput" => { 
      $output | str join "\n"
    },
    "GrantedAssume" => {
      for v in $var_names {
        hide-env -i $v
      }
      let values = $command | skip 1
      let vars = $var_names |
        zip $values |
        filter {|x| $x.1 != "None"} |
        reduce --fold {} {|it, acc| $acc | insert $it.0 $it.1} 
      load-env $vars
    },
    "GrantedDesume" => {
      for v in $var_names {
        hide-env -i $v
      }
    },
    _ => {
      # most likely no output, so nothing to do
    }
  }
}

[abusch]

I've updated it to support the latest --exec changes, if anyone is interested: https://gist.github.com/abusch/aadadfdfe4684813945daed7a4a052d6

[FollowTheProcess]

This doesn't work when you don't enter a role i.e just run assume and use the interactive picker. However I've made some tweaks to a local copy and it seems to work well:

  # Run assumego and collect its output
  let output = with-env {GRANTED_ALIAS_CONFIGURED: "true"} {
    assumego ...$args
  }

  let granted_output = $output | lines
  let granted_status = $env.LAST_EXIT_CODE

Basically don't pipe it to collect, the interactive prompt is sent to stderr so we can still pick and get the GrantedAssume ... string out :)

[abusch]

Ah yeah, it looks like I did update my local script in exactly the same way you did :) I've updated the gist with what I have in case someone else stumbles upon it.