-
Notifications
You must be signed in to change notification settings - Fork 4
LADValenceChange
My current work is on adding a valence change library to the Grammar Matrix customization system (Bender et al., 2010). The approach I'm investigating is providing rule components (building blocks) that are applicable cross-linguistically, which the grammar engineer can assemble into full rules using the customization system.
Ultimately the library will support valence-decreasing operations and valence-increasing operations; for the purpose of this session I'm concentrating on the causative, using primarily illustrative examples from Lakota.
Lakota is a language in the Siouan family, spoken in conjunction with its mutually-intelligible siblings Eastern Dakota (Santee-Sisseton) and Western Dakota (Yankton-Yakntonai) dialects, by approximately 2,000 speakers in the United States and Canada, with the largest populations in North and South Dakota.
Word order is basically SOV and postpositional, though overt nominals are optional: 3rd person subject and object are unmarked, while other PNs are marked by a system of verbal pronominal affixes. Stress is phonemic but in the presence of affixation strongly tends to move forward to not later than the second syllable. Many verbs and a few nouns and enclitics undergo lexically-conditioned ablaut in their final vowel, realized as -a /a/, -e /ɛ/, or -iŋ /ɪ̃/; in dictionary citation form ablaut targets are denoted by a final capital A.
The straightforward causative is formed from transitive verbs with the suffix -khiyA as illustrated in (1) and (2) below, along with the corresponding MRSes:
1a. igmú kiŋ wakhúwa
igmú kiŋ wa-khuwá
cat DET 1SG.A-chase
"I chased the cat"
b. [ LTOP: h1 INDEX: e2
RELS: < ["_cat_n_rel" LBL: h3 ARG0: x4 ]
["exist_q_rel" LBL: h5 ARG0: x4 RSTR: h6 BODY: h7 ]
["_chase_v_rel" LBL: h8 ARG0: e2 ARG1: x9 [ PNG 1sg ] ARG2: x4 ] >
HCONS: < h6 qeq h3 h1 qeq h8 > ]
2a. igmú kiŋ mayakhúwakhiye
igmú kiŋ ma-ya-khuwá-khiyA
cat DET 1SG.P-2SG.A-chase-CAUS.TR
"You made me chase the cat" (or "you made the cat chase me")
b. [ LTOP: h1 INDEX: e10
RELS: < ["_cat_n_rel" LBL: h3 ARG0: x4 ]
["exist_q_rel" LBL: h5 ARG0: x4 RSTR: h6 BODY: h7 ]
["_chase_v_rel" LBL: h8 ARG0: e2 ARG1: x9 [ PNG 1sg ] ARG2: x4 ]
["_cause_v_2_rel" LBL: h11 ARG0: e10 ARG1: x12 [ PNG 2sg ] ARG2: x9 ARG3: h13 ] >
HCONS: < h6 qeq h3 h1 qeq h11 h13 qeq h8> ]
(Ullrich, 2011)
(NB. For convenience in this discussion I use English lemmas for PRED values.)
Some transitive verbs form the causative with -yA in mostly-complementary distribution with -khiyA; however, for a few verbs it is contrastive: -yA expresses accidental or unintentional causation, while -khiyA volitional.
Stative verbs are pervasive in Lakota, filling e.g. the role played by adjectives in English. Stative verbs can transitivized via the causative affix -yA, as here:
3a. hayápi kiŋ púze
hayápi kiŋ púzA
clothes DET be.dry
"The clothes are dry"
b. [ LTOP: h1 INDEX: e2
RELS: < [ "_clothes_n_rel" LBL: h3 ARG0: x4 ]
[ "exist_q_rel" LBL: h5 ARG0: x4 RSTR: h6 BODY: h7 ]
[ "_dry_a_rel" LBL: h8 ARG0: e2 ARG1: x4 ] >
HCONS: < h6 qeq h3 h1 qeq h8 > ]
4a. hayápi kiŋ puswáye
hayápi kiŋ púzA-wa-yA
clothes DET be.dry-1SG.A-CAUS.INTR
"I dried the clothes"
b. [ LTOP: h1 INDEX: e2
RELS: < [ "_clothes_n_rel" LBL: h3 ARG0: x4 ]
[ "exist_q_rel" LBL: h5 ARG0: x4 RSTR: h6 BODY: h7 ]
[ "_dry_a_rel" LBL: h8 ARG0: e2 ARG1: x4 ]
[ "_cause_v_1_rel" LBL: h11 ARG0: e10 ARG1: x12 [ PNG 1sg ] ARG2: h13 ] >
HCONS: < h6 qeq h3 h1 qeq h11 h13 qeq h8 > ]
(Van Valin, 1977)
-yA exists in mostly-complementary distribution with the "instrumental causative" (Rood and Taylor, 1996) prefix yu-:
5a. wašté b. tónačhaŋ yuwášte-he
Ø-wašté tónačhaŋ yu-Ø-Ø-wášte=he
3SG.P-be.good for.several.days CAUS.INTR-3SG.P-3SG.A-be.good=CONT
"It is good" "He kept improving it for several days"
Stative verbs expressing size/shape or value judgments generally form the causative with yu-, while other do so with -yA. In a few instances, both forms are possible, giving contrastive meanings:
6a. ska b. skayé c. yuská
Ø-ská Ø-Ø-ská-yA Ø-Ø-yu-ská
3SG.P-be.white 3SG.P-3SG.A-be.white-CAUS.INTR 3SG.P-3SG.A-CAUS.INTR-be.white
"It is white" "He painted it white" "He cleansed it"
(Ullrich, 2011)
Causatives formed from statives can also transitivized via the causative:
7a. hayápi kiŋ pusmáyayekhiye
hayápi kiŋ púzA-ma-yÁ-ya-khiyA
clothes DET dry-1SG.P-CAUS.INTR-2SG.A-CAUS.TR
"You made me dry the clothes"
b. [ LTOP: h1 INDEX: e15
RELS: < [ "_clothes_n_rel" LBL: h3 ARG0: x4 ]
[ "exist_q_rel" LBL: h5 ARG0: x4 RSTR: h6 BODY: h7 ]
[ "_dry_a_rel" LBL: h8 ARG0: e2 ARG1: x4 ]
[ "_cause_v_1_rel" LBL: h11 ARG0: e10 ARG1: x12 [ PNG 1sg ] ARG2: h13 ]
[ "_cause_v_2_rel" LBL: h14 ARG0: e15 ARG1: x16 [ PNG 2sg ] ARG2: x12 ARG3: h17 ] >
HCONS: < h6 qeq h3 h1 qeq h14 h13 qeq h8 h17 qeq 11 > ]
Given this data, it appears that to implement the causative in Lakota we need two operations (and so two implementing rules):
- Addition of a subject argument
- Addition of a scopal predication
To expand this idea by way of contrast, we can compare to the causative in Japanese:
8a. Suzuki-ga keeki-o tabeta
Suzuki-NOM cake-ACC eat.PST
"Suzuki ate the cake."
b. Aoki-ga Suzuki-ni keeki-o tabesaseta
Aoki-NOM Suzuki-DAT cake-ACC eat.CAUS.PST
"Aoki made Suzuki eat the cake."
(Sag et al., 2003)
For Japanese, we need same two elements needed for Lakota, plus a third:
-
Addition of a subject argument
-
Addition of a scopal predication
-
Change of case frame
Now we can look at how these rule components might be implemented.
The scopal predicate rule is fairly straightforward:
9. add-scopal-arg123-pred-lex-rule := lex-rule &
[ SYNSEM [ LOCAL [ CAT.VAL [ SPR.FIRST.LOCAL.CONT.HOOK [ LTOP #handle,
XARG #oldsubj ],
SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX #subj ],
CONT [ HOOK [ LTOP #top,
INDEX #evt,
XARG #subj ],
RELS <! #key !>,
HCONS <! qeq & [ HARG #scoped-evt,
LARG #handle ] !> ] ],
LKEYS.KEYREL #key & arg123-relation & [ LBL #top,
ARG0 #evt,
ARG1 #subj,
ARG2 #oldsubj,
ARG3 #scoped-evt ] ]
DTR.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.XARG #oldsubj ].
When adding a subject argument, we also need to make sure the non-local dependencies get properly appended:
10. add-subj-arg-lex-rule := lex-rule &
[ SYNSEM [ SUBJ.FIRST.LOCAL.CONT.HOOK.XARG.SYNSEM.NON-LOCAL [ SLASH [ LIST #sfirst, LAST #smiddle ],
QUE [ LIST #qfirst, LAST #qmiddle ],
REL [ LIST #rfirst, LAST #rmiddle ] ],
NON-LOCAL [ SLASH [ LIST #sfirst, LAST #slast ],
QUE [ LIST #qfirst, LAST #qlast ],
REL [ LIST #rfirst, LAST #rlast ] ] ],
DTR.NON-LOCAL [ SLASH [ LIST #smiddle, LAST #slast ],
QUE [ LIST #qmiddle, LAST #qlast ],
REL [ LIST #rmiddle, LAST #rlast ] ] ].
These rule components are envisioned to be language-independent and provided by the valence change library. A case-changing rule component necessarily needs language-specific case information and would be created by the customization system.
For example, a case-changing rule for Japanese would look something like this:
11. caus-case-lex-rule := lex-rule &
[ SYNSEM.LOCAL [ CAT.VAL [ SPR [ FIRST.LOCAL [ CONT.HOOK.XARG #causee,
CAT.VAL.COMPS.FIRST #obj-val ] ],
COMPS < #obj-val,
[ LOCAL [ CAT.HEAD.CASE ni,
CONT.HOOK.INDEX #causee ] ] > ] ]
DTR.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.XARG #causee ].
(In fact, this is essentially how JaCY implements case frame change, but in a lexical rule, instead of a lexical type.)
Using this approach, with the mechanics provided by the customization system library, the causative rule in the implemented grammar would simply need to add a PRED value and (and any other desired constraints):
12. caus-pred-lex-rule := val-change-only-lex-rule & add-subj-arg-lex-rule & add-scopal-arg123-pred-lex-rule &
[ LKEYS.KEYREL.PRED "_cause_v_rel" ].
Q1: Are there contexts in which this compositional approach to building valence-changing rules would not make sense?
Q2: add-subj-arg-lex-rule digs deeply into its SUBJ's CONT.HOOK.XARG; is this reasonable? Problematic?
Q3: add-subj-arg-lex-rule doesn't mess with ARG-ST; should it?
The question of what, if anything, to do with ARG-ST under valence change is a topic we started discussing as a group of Emily's students and summarized to the MATRIX-DEV mailing list, reproduced here:
-
The big-picture question is: do valence-changing rules manipulate ARG-ST, VAL, or both? If, for example, a valence reduction suppresses an argument directly on ARG-ST, then one thing that gets lost is the use of ARG-ST as a precedence setter for binding relations. (Which may or may not be a problem for a particular grammar, and may or may not be something we want to worry too much over?)
One of the functions of ARG-ST is as the locus for keeping track of long-distance dependencies. If basic-one-arg is the mother of a lexical rule, then we need to break the connection between the mother’s NON-LOCAL and the daughter’s NON-LOCAL. Looking at basic-two- arg, there are three diff list appends (SLASH, REL, and QUE) that implement the head-threading analysis of Bouma, Malouf, and Sag (2001 and/or 1998 - not sure which). (Note that we treat modifiers separately.) With a suppressed argument, what we need to worry about is that all those diff lists were empty (of type unexpressed).
So there are three cases to consider:
- In the case of a suppressed argument, the DTR needs to say that the suppressed argument is type unexpressed.
- In the case where e.g. we “demote” an argument from an NP to PP, if we don’t copy the entire SYNSEM of the argument up, then we need to copy up at least the NON-LOCAL values.
- In the case of an added argument: in order to get any gaps appropriately integrated, the mother of the rule needs to define its own NON-LOCAL values as the diff-list-append of the DTRs NON-LOCAL values and the new argument’s NON-LOCAL values.
(add-subj-arg-lex-rule was created specifically to address point #3.)
Q4: Generally, what should valence-changing operations do or not do with ARG-ST, VAL, or both?
Now we come back to the intransitive causative motivated by the Lakota data. We want another rule component, similar to (9), to handle the structural differences:
12. add-scopal-arg12-pred-lex-rule := lex-rule &
[ SYNSEM [ LOCAL [ CAT.VAL [ SPR.FIRST.LOCAL.CONT.HOOK [ LTOP #handle,
XARG #oldsubj ],
SUBJ.FIRST.LOCAL.CONT.HOOK.INDEX #subj ],
CONT [ HOOK [ LTOP #top,
INDEX #evt,
XARG #subj ],
RELS <! #key !>,
HCONS <! qeq & [ HTOP #scoped-evt,
LTOP #handle ] !> ] ],
LKEYS.KEYREL #key & arg12-relation & [ LBL #top,
ARG0 #evt,
ARG1 #subj,
ARG2 #scoped-evt ] ]
DTR.LOCAL.CAT.VAL.SUBJ.FIRST.LOCAL.CONT.HOOK.XARG #oldsubj ].
This brings up some additional questions:
Q5: The old subject doesn't get added to the causative EP. Does this matter?
Q6: In my implemented Lakota grammar, statives inherit from intransitive-lex-item (and therefore basic-one-arg-no-hcons); given the possibility of transitivization, does this analysis make sense?
-
Bender, E. M., Drellishak, S., Fokkens, A., Poulson, L., & Saleem, S. (2010) Grammar customization. Research on Language & Computation, 8(1), 23-72.
-
Rood, D. S., & Taylor, A. R. (1996) Sketch of Lakhota, a Siouan language. In Handbook of North American Indians (Vol. 17, pp. 440-82). Washington, DC: Smithsonian Institution.
-
Sag, I. A., Wasow, T., and Bender, E.M. (2003) Syntactic Theory: A Formal Introduction. Stanford, CA: CSLI.
-
Ullrich, J. (2011) New Lakota Dictionary (2nd ed.). Bloomington, IN: Lakota Language Consortium.
-
Van Valin, R. D. (1977) Aspects of Lakhota Syntax: A Study of Lakhota (Teton Dakota) Syntax and Its Implications for Universal Grammar (Doctoral dissertation). University of California, Berkeley.
Home | Forum | Discussions | Events